electro-music.com   Dedicated to experimental electro-acoustic
and electronic music
 
    Front Page  |  Articles  |  Radio
 |  Media  |  Forum  |  Wiki  |  Links  |  Store
Forum with support of Syndicator RSS
 FAQFAQ   CalendarCalendar   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   LinksLinks
 RegisterRegister   ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in  Chat RoomChat Room 
 Forum index » DIY Hardware and Software » ChucK programming language
Kewl ChucK Song
Post new topic   Reply to topic Moderators: Kassen
Page 1 of 2 [39 Posts]
View unread posts
View new posts in the last week
Mark the topic unread :: View previous topic :: View next topic
Goto page: 1, 2 Next
Author Message
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Sat Nov 01, 2008 3:29 am    Post subject: Kewl ChucK Song
Subject description: Automagically Generated
Reply with quote  Mark this post and the followings unread

I have created an automatic ChucK song generator based on my Boolean Sequencing and kijjaz's guitar and bass drums. It produces random songs, and about one in 10 is really good to my ear. I would like to add other instruments, what do you suggest? Any other drums to add, kijjaz?


Industrial.mp3
 Description:
Kewl ChucK Song

Download
 Filename:  Industrial.mp3
 Filesize:  1.28 MB
 Downloaded:  481 Time(s)


_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Antimon



Joined: Jan 18, 2005
Posts: 3734
Location: Sweden
Audio files: 277
G2 patch files: 96

PostPosted: Sun Nov 02, 2008 2:01 am    Post subject: Reply with quote  Mark this post and the followings unread

Interesting note sequences. I like the kick drum sound.

/Stefan

_________________
Antimon's Window
@soundcloud @Flattr home - you can't explain music
Back to top
View user's profile Send private message Visit poster's website
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Sun Nov 02, 2008 3:12 am    Post subject: Reply with quote  Mark this post and the followings unread

I have one idea for the melody generation.

I'd like to try this:
create an array which contains a serie of notes of a melody / motif / riff

for example,
[0, 10, 12, 0, 5, 7, 3, 3] @=> int melody1[];
if started on C, would be note C Bb C' C F G Eb Eb

then, the generated notes from your sequencer can be mapped to choose notes from this sequence.
or to reset / restart index for reading from the sequence.

with this, we can play more with a particular set of notes, not just chromatic scale.
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Sun Nov 02, 2008 4:59 am    Post subject: Reply with quote  Mark this post and the followings unread

Thanks, I kinda like the songs that this thing generates. Interesting idea, kijjaz, that would lend itself very well to playing scales on the guitar. From what I've learned, you study the scales because the notes of the scales sound good togther, then you practice various techniques of playing the scale notes in various sequences to create songs.

I'm not sure what the mapping would be, I'll have to think of that, but anyway what I would do is put a scale in your array and then index the array with the boolean sequencer somehow. I'll have to think about ways to do the mapping, coolness.

_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Sun Nov 02, 2008 12:49 pm    Post subject: Reply with quote  Mark this post and the followings unread

Yes, I guess that would do the trick nicely.

I'm thinking about these ways, they can be implemented seperately:

- having a BaseNote value which is the root of the riff it's playing,
but have the mechanism in the program shifting this BaseNote value around for chord-change effect
- start index from 0 and increase by 1, when it reaches the end of the array, restart it at 0
and have some conditions from the boolean sequencing setting the index's position/speed/reset
(this would play the riff out clearly, but it'd be rearranged)
- having more complex rhythm, duration of the notes.
this should depend on creating another function then sporking it and letting run simultaneously.
rhythm (durations) can be put into an array.
- the guitar can play both sustained and staccato (short) notes.
shorter notes can be created by noteOff(velocity) sooner.
- adjusting guitar's pluck position by conditions from the boolean sequencer for different timbers each stroke.
- applying damping to the guitar sound for the 'mute' effect on guitar

etc.. i think these things would become handy and fun to play with / listen to ^_^
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Sun Nov 02, 2008 1:30 pm    Post subject: Reply with quote  Mark this post and the followings unread

hi.. Inventor, these example is what i've been trying to practice myself for creating some of the effects i'm referring to.

Code:
// guitar riff modification technics
// Copyright 2008 by Kijjasak Triyanond (kijjaz@yahoo.com)
// This software is protected by GPL version 3
140.0 * 2 => float BPM;
minute / BPM => dur beat;

Mandolin s => Dyno compressor => LPF s_lpf => SinOsc od => dac;
pi => s.gain; // Drive Gain
compressor.compress(); // set as compressor
.25 => compressor.thresh; // set threshold
s_lpf.set(1900, 1.5); // set lowpass filter as amp EQ simulation
1 => od.sync; // set od as sine overdrive

[0, 0, 12, 0, 0, 0, 12, 0, 0, 7, 10, 12, 6, 5, 7, -2] @=> int melody1[];
[1.0, 1, 1.5, 1.5, .5, .5, 1.5, 1.5, .5, .5, .5, .5, 1, 1, 1.5, 1.5] @=> float rhythm1[];

32 => int BaseNote;

int i1, i2;
while(true)
{
    melody1[i1] + BaseNote => Std.mtof => s.freq;
   
    // play legato (long) or staccato (short) notes
    if(i2 % 4 != 1)
    {
        .8 => s.noteOn;
        rhythm1[i2]::beat * .95 => now;
        .8 => s.noteOff;
        rhythm1[i2]::beat * .05 => now;
    }
    else
    {
        .5 => s.noteOn; // play softer, and shorter
        rhythm1[i2]::beat * .4 => now;
        .5 => s.noteOff;
        rhythm1[i2]::beat * .6 => now;
    }
   
    // move plucking position
    if(i2 % 3 == 0)
    {
        0.1 => s.pluckPos;
    }
    else
    {
        1.0/3 => s.pluckPos;
    }
   
    (i1 + 1) % melody1.cap() => i1;
    (i2 + 1) % rhythm1.cap() => i2;
}


Code:
// guitar riff modification technics
// Copyright 2008 by Kijjasak Triyanond (kijjaz@yahoo.com)
// This software is protected by GPL version 3
140.0 * 2 => float BPM;
minute / BPM => dur beat;

Mandolin s => Dyno compressor => LPF s_lpf => SinOsc od => dac;
pi => s.gain; // Drive Gain
compressor.compress(); // set as compressor
.25 => compressor.thresh; // set threshold
s_lpf.set(1900, 1.5); // set lowpass filter as amp EQ simulation
1 => od.sync; // set od as sine overdrive

[0, 0, 12, 0, 0, 0, 12, 0, 0, 7, 10, 12, 6, 5, 7, -2] @=> int melody1[];
[1.0, 1, 1.5, 1.5, .5, .5, 1.5, 1.5, .5, .5, .5, .5, 1, 1, 1.5, 1.5] @=> float rhythm1[];

32 => int BaseNote;

int i1, i2;
while(true)
{
    melody1[i1] + BaseNote => Std.mtof => s.freq;
   
    // play legato (long) or staccato (short) notes
    if(i2 % 4 != 1)
    {
        .8 => s.noteOn;
        rhythm1[i2]::beat * .95 => now;
        .8 => s.noteOff;
        rhythm1[i2]::beat * .05 => now;
    }
    else
    {
        .5 => s.noteOn; // play softer, and shorter
        rhythm1[i2]::beat * .4 => now;
        .5 => s.noteOff;
        rhythm1[i2]::beat * .6 => now;
    }
   
    // move plucking position
    if(i2 % 3 == 0)
    {
        0.1 => s.pluckPos;
    }
    else
    {
        1.0/3 => s.pluckPos;
    }
   
    if (i1 % 3 == 2) 68 - BaseNote => BaseNote; // change root note of the riff sometimes
    (i1 + 1) % melody1.cap() => i1;
    (i2 + i1) % rhythm1.cap() => i2; // messing around with rhythm index
}   


Code:
// guitar riff modification technics
// Copyright 2008 by Kijjasak Triyanond (kijjaz@yahoo.com)
// This software is protected by GPL version 3
140.0 * 2 => float BPM;
minute / BPM => dur beat;

Mandolin s => Dyno compressor => LPF s_lpf => SinOsc od => dac;
pi => s.gain; // Drive Gain
compressor.compress(); // set as compressor
.25 => compressor.thresh; // set threshold
s_lpf.set(1900, 1.5); // set lowpass filter as amp EQ simulation
1 => od.sync; // set od as sine overdrive

[0, 0, 12, 0, 0, 0, 12, 0, 0, 7, 10, 12, 6, 5, 7, -2] @=> int melody1[];
[1.0, 1, 1.5, 1.5, .5, .5, 1.5, 1.5, .5, .5, .5, .5, 1, 1, 1.5, 1.5] @=> float rhythm1[];

32 => int BaseNote;

int i1, i2;
while(true)
{
    melody1[i1] + BaseNote => Std.mtof => s.freq;
   
    // play legato (long) or staccato (short) notes
    if(i2 % 4 != 1)
    {
        .8 => s.noteOn;
        rhythm1[i2]::beat * .95 => now;
        .8 => s.noteOff;
        rhythm1[i2]::beat * .05 => now;
    }
    else
    {
        .5 => s.noteOn; // play softer, and shorter
        rhythm1[i2]::beat * .4 => now;
        .5 => s.noteOff;
        rhythm1[i2]::beat * .6 => now;
    }
   
    // move plucking position
    if(i2 % 3 == 0)
    {
        0.1 => s.pluckPos;
    }
    else
    {
        1.0/3 => s.pluckPos;
    }
   
    if (i1 % 8 == 7) 68 - BaseNote => BaseNote; // change root note of the riff sometimes
    (i1 + i2) % melody1.cap() => i1; // messing around with melody index
    (i2 + 1) % rhythm1.cap() => i2;
}


Code:
// guitar riff modification technics
// Copyright 2008 by Kijjasak Triyanond (kijjaz@yahoo.com)
// This software is protected by GPL version 3
160.0 * 2 => float BPM;
minute / BPM => dur beat;

Mandolin s => Dyno compressor => LPF s_lpf => SinOsc od => dac;
pi => s.gain; // Drive Gain
compressor.compress(); // set as compressor
.25 => compressor.thresh; // set threshold
s_lpf.set(1900, 1.5); // set lowpass filter as amp EQ simulation
1 => od.sync; // set od as sine overdrive

[0, 0, 12, 0, 0, 0, 12, 0, 0, 7, 10, 12, 6, 5, 7, -2] @=> int melody1[];
[1.0, 1, 1.5, 1.5, .5, .5, 1.5, 1.5, .5, .5, .5, .5, 1, 1, 1.5, 1.5] @=> float rhythm1[];

32 => int BaseNote;

int i1, i2;
while(true)
{
    melody1[i1] + BaseNote => Std.mtof => s.freq;
   
    for(int iter; iter < Std.rand2(1, 2); iter++)
    {
           
        // play legato (long) or staccato (short) notes
        if(i2 % 4 != 1)
        {
            .8 => s.noteOn;
            rhythm1[i2]::beat * .95 => now;
            .8 => s.noteOff;
            rhythm1[i2]::beat * .05 => now;
        }
        else
        {
            .5 => s.noteOn; // play softer, and shorter
            rhythm1[i2]::beat * .4 => now;
            .5 => s.noteOff;
            rhythm1[i2]::beat * .6 => now;
        }
    }
   
    // move plucking position
    if(i2 % 3 == 0)
    {
        0.1 => s.pluckPos;
    }
    else
    {
        1.0/3 => s.pluckPos;
    }
   
    if (i1 % 5 == 4) 76 - BaseNote => BaseNote; // change root note of the riff sometimes
    (i1 + 1) % melody1.cap() => i1;
    (i2 + 1) % rhythm1.cap() => i2;
}


I think this kind of ideas can work very well with your enormous outputs from your boolean sequencer.


20081103GuitarRiff-01.ck
 Description:
starting point, playing the riff normally.

Download
 Filename:  20081103GuitarRiff-01.ck
 Filesize:  1.35 KB
 Downloaded:  141 Time(s)

Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
Kassen
Janitor
Janitor


Joined: Jul 06, 2004
Posts: 7678
Location: The Hague, NL
G2 patch files: 3

PostPosted: Sun Nov 02, 2008 2:09 pm    Post subject: Reply with quote  Mark this post and the followings unread

I like it a lot, Les. I hope you'll extend it with some song structure and maybe more lyrics some day. Maybe it's a weird suggesting but did you think of trying a detuned sax with this? I'm experiencing it as quite "no-wave"-ish and no-wave works with sax.

http://en.wikipedia.org/wiki/No_Wave

_________________
Kassen
Back to top
View user's profile Send private message Send e-mail Visit poster's website
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Sun Nov 02, 2008 3:27 pm    Post subject: Reply with quote  Mark this post and the followings unread

Thanks guys! I know what I'll be doing tonight! Adding some No Wave sax and kijjaz's code to the strat program, for sure. I had never even heard of No Wave, and it sounds cool.

But I cannot call it mine alone since kijjaz has made so many contributions. You know, I see a trend. kijjaz makes the bits and pieces, then I stitch them together into an application based on the boolean sequencing framework. Nice combination, don't you think?

I will work on it some more soon. Maybe I will call it "Know Wave", for "Kijjaz No Wave".

"Let's make noise for peace!" - kijjaz

_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Kassen
Janitor
Janitor


Joined: Jul 06, 2004
Posts: 7678
Location: The Hague, NL
G2 patch files: 3

PostPosted: Sun Nov 02, 2008 3:50 pm    Post subject: Reply with quote  Mark this post and the followings unread

No-Wave style sax is quite hard to describe (actually it could be argued that No-Wave itself is impossible to define...). Erm... imagine a saxophonist who is quite good at making a sax make all sorts of noises but not at all influenced by traditional sax playing. It's mostly in the rhythm and the timbre, these are repetitive distorted and often borderline a-tonal but still "musical". We're talking about a lot of noise but noise made by musicians with more control over their instrument then the average punk guitarist.

I'd hook up STK's Saxophony to your riff generators, then tweak the member functions until you start wondering "is this still a sax?", that should about do it ;¬).

So far for the music-history lesson.... go whatever you think feels right but I think a angle like that could be more exciting then going with more plain strings and edging towards a sort of "minimal wave" sound, I've become a bit tired of that, even if there are of course very interesting pieces in that style as well.

_________________
Kassen
Back to top
View user's profile Send private message Send e-mail Visit poster's website
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Sun Nov 02, 2008 5:37 pm    Post subject: Reply with quote  Mark this post and the followings unread

OK Kas, I did just that - added the sax and made it funky. All of the sax parameters are varied with weighted probability functions. Now because of the variability, only one song in 25 or so is "good", but that's ok, I just keep hitting the enter key.

I have not yet added kijjaz's scale stuff for the guitar. Does anyone know of a source for scales as MIDI notes in an array? I know, Google is my friend...

I'm calling it "KNoW", for "Kijjaz No Wave"! A tribute to our buddy kijjaz.


KNoW12.mp3
 Description:

Download
 Filename:  KNoW12.mp3
 Filesize:  787.75 KB
 Downloaded:  351 Time(s)


_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Kassen
Janitor
Janitor


Joined: Jul 06, 2004
Posts: 7678
Location: The Hague, NL
G2 patch files: 3

PostPosted: Sun Nov 02, 2008 6:29 pm    Post subject: Reply with quote  Mark this post and the followings unread

I love it!
_________________
Kassen
Back to top
View user's profile Send private message Send e-mail Visit poster's website
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Sun Nov 02, 2008 9:04 pm    Post subject: Reply with quote  Mark this post and the followings unread

Inventor, thanks.

Wow.. No-Wave is that kind of thing. i love the idea.
i found myself playing around with a sax and get some weird sounds.

i've just listened to KNoW .. ohhh
nice jam in there!! wow. heheh i like how they respond to eachother in the patch.
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 12:49 am    Post subject: Reply with quote  Mark this post and the followings unread

KNoW = Kijjaz No Wave

To hear the songs I made with this generator prior to adding the sax, go here:

http://virb.com/inventor

It starts on the fourth song, which is the second album called "Boolean Sequencing", but you might like the first three songs from the "Paranoid Schizophrenia" album also.

I will continue to add new songs once I have enough for another album.

Maybe later tonight I'll add the scales...

_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Kassen
Janitor
Janitor


Joined: Jul 06, 2004
Posts: 7678
Location: The Hague, NL
G2 patch files: 3

PostPosted: Mon Nov 03, 2008 9:36 am    Post subject: Reply with quote  Mark this post and the followings unread

Les, my radio-show is only a small one on local radio (but it has internet streaming as well)... and it's in the middle of the night... but if you send me stuff you can be on the radio; I like your music.
_________________
Kassen
Back to top
View user's profile Send private message Send e-mail Visit poster's website
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 10:40 am    Post subject: Reply with quote  Mark this post and the followings unread

Kassen wrote:
Les, my radio-show is only a small one on local radio (but it has internet streaming as well)... and it's in the middle of the night... but if you send me stuff you can be on the radio; I like your music.


Woohoo, Kassen, you made my day! To be on the air half a world away in the middle of the night would be fantastic! I'll send you all of my current songs, though that will be a few separate emails. Yipee!

_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
radarsat1



Joined: Mar 14, 2008
Posts: 85
Location: Montreal

PostPosted: Mon Nov 03, 2008 12:20 pm    Post subject: Reply with quote  Mark this post and the followings unread

Kassen wrote:
(but it has internet streaming as well)...


url?
Back to top
View user's profile Send private message
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 1:08 pm    Post subject: Reply with quote  Mark this post and the followings unread

Hey Kijjaz, I just arranged for you to receive a free Guitar Motion Sensor. Cool! Check your private messages on electro-music.com.
_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 2:12 pm    Post subject: Reply with quote  Mark this post and the followings unread

So, um, what I have not yet figured out is how to represent a scale as an array of MIDI notes. I'd like to use Kijjaz's proposed technique of having a basenote and the array contains relative notes that form the scale. Any scale will do. Could someone who understands this describe it or post such an array? I'd appreciate it, as I cannot proceed without it. Thanks in advance.
_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Mon Nov 03, 2008 2:48 pm    Post subject: Reply with quote  Mark this post and the followings unread

some standard western musical theory scales:

Major Pentatonic [0, 2, 4, 7, 9]
Minor Pentatonic [0, 3, 5, 7, 10]

Lydian Mode [0, 2, 4, 6, 7, 9, 11]
Major scale (Ionian mode) [0, 2, 4, 5, 7, 9, 11]
Mixolydian Mode [0, 2, 4, 5, 7, 9, 10]
Lydian Mode [0, 2, 3, 5, 7, 9, 10]
Aeolian Mode [0, 2, 3, 5, 7, 8, 10]
Phrygian Mode [0, 1, 3, 5, 7, 8, 10]
Locrian Mode [0, 1, 3, 5, 6, 8, 10]

(Ascending) Melodic Minor [0, 2, 3, 5, 7, 9, 11]
Harmonic Minor [0, 2, 3, 5, 7, 8, 11]

example blues scale within 7 notes:
[0, 3, 5, 6, 7, 9, 10], [0, 2, 3, 5, 6, 9, 10]
[0, 3, 4, 5, 6, 7, 10], [0, 3, 4, 6, 7, 9, 10]

i'll post a way to generate midi note from an input note and these scales later.
now gotta sleep ^_^. take care all.
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 3:28 pm    Post subject: Reply with quote  Mark this post and the followings unread

Thanks, kijjaz, that was SOOO helpful! I have already begun coding it up! Should have something in place tonight.
_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 4:50 pm    Post subject: Reply with quote  Mark this post and the followings unread

Well, I put in the major pentatonic scale with two octaves and I am running both the guitar and the sax from it. I must say the sound is greatly improved! It actually sounds more like music now. Here is a short example:


KNoW16.mp3
 Description:
A short active song

Download
 Filename:  KNoW16.mp3
 Filesize:  227.75 KB
 Downloaded:  382 Time(s)


_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
kijjaz



Joined: Sep 20, 2004
Posts: 765
Location: bangkok, thailand
Audio files: 4

PostPosted: Mon Nov 03, 2008 9:32 pm    Post subject: Reply with quote  Mark this post and the followings unread

I give you this function for using the scale arrays easily:

Code:
fun float NoteToMidi(int key, int note, int scale[])
{
    0 => int octave;
   
    if (note < 0) // quite a Brute-Force way to count octave from note
    {       
        while(note < 0)
        {
            octave--;
            scale.cap() +=> note;
        }
    } else
    {
        note / scale.cap() +=> octave;
        note % scale.cap() => note;
    }
   
    return (key + octave * 12 + scale[note]) $ float;
}

// test code
[0, 2, 4, 5, 7, 9, 10] @=> int MixolydianMode[];
for(-10 => int i; i < 10; i++)
{
    <<< i, NoteToMidi(60, i, MixolydianMode) >>>;
}
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger MSN Messenger
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 10:31 pm    Post subject: Reply with quote  Mark this post and the followings unread

Thanks kijjaz, I put that in my program, it works great.
_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Mon Nov 03, 2008 10:44 pm    Post subject: Reply with quote  Mark this post and the followings unread

Here is a song that uses your function, kijjaz. I added a feature that sets a random number of octaves for the song and if it walks to the upper or lower boundary, it rotates to the other boundary. This one walks up in frequency a few times before wrapping around. The sax and drums are prominent here.


KNoW_Octaves.mp3
 Description:
A song spanning three octaves

Download
 Filename:  KNoW_Octaves.mp3
 Filesize:  2.56 MB
 Downloaded:  395 Time(s)


_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Inventor
Stream Operator


Joined: Oct 13, 2007
Posts: 5978
Location: San Antonio, Tx, USA
Audio files: 258

PostPosted: Tue Nov 04, 2008 4:24 am    Post subject: Reply with quote  Mark this post and the followings unread

Does anyone have a good hi-hat model that I can add to the program? Thanks.
_________________
"Let's make noise for peace." - Kijjaz
Back to top
View user's profile Send private message Send e-mail
Display posts from previous:   
Post new topic   Reply to topic Moderators: Kassen
Page 1 of 2 [39 Posts]
View unread posts
View new posts in the last week
Goto page: 1, 2 Next
Mark the topic unread :: View previous topic :: View next topic
 Forum index » DIY Hardware and Software » ChucK programming language
Jump to:  

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum
e-m mkii

Please support our site. If you click through and buy from
our affiliate partners, we earn a small commission.


Forum with support of Syndicator RSS
Powered by phpBB © 2001, 2005 phpBB Group
Copyright © 2003 through 2009 by electro-music.com - Conditions Of Use